使用 `Meson`#

注意

本文档的很大一部分已过时。您可以运行 f2py 并使用 --build-dir 来获取一个骨架 Meson 项目，其中已设置了基本依赖项。

版本 1.26.x 中已更改：现在 f2py 的默认构建系统是 Meson，有关更多详细信息，请参阅 numpy.distutils 的状态和迁移建议。

与使用 numpy.distutils 中描述的技术相比，利用 Meson 的主要优势在于它可以轻松地融入现有系统和更大的项目。 Meson 拥有相当 Pythonic 的语法，这使得它对 Python 用户来说更加舒适和易于扩展。

斐波那契教程 (F77)#

在使用像 Meson 这样的通用构建系统之前，我们需要生成 C 包装器。我们将通过以下方式获取它：

python -m numpy.f2py fib1.f -m fib2

现在，请考虑以下 Meson.build 文件，用于三种封装方式 - 入门部分中的 fib 和 scalar 示例。

project('f2py_examples', 'c',
  version : '0.1',
  license: 'BSD-3',
  meson_version: '>=0.64.0',
  default_options : ['warning_level=2'],
)

add_languages('fortran')

py_mod = import('python')
py = py_mod.find_installation(pure: false)
py_dep = py.dependency()

incdir_numpy = run_command(py,
  ['-c', 'import os; os.chdir(".."); import numpy; print(numpy.get_include())'],
  check : true
).stdout().strip()

incdir_f2py = run_command(py,
    ['-c', 'import os; os.chdir(".."); import numpy.f2py; print(numpy.f2py.get_include())'],
    check : true
).stdout().strip()

inc_np = include_directories(incdir_numpy, incdir_f2py)

py.extension_module('fib2',
  [
    'fib1.f',
    'fib2module.c',  # note: this assumes f2py was manually run before!
  ],
  incdir_f2py / 'fortranobject.c',
  include_directories: inc_np,
  dependencies : py_dep,
  install : true
)

此时构建将完成，但导入会失败。

meson setup builddir
meson compile -C builddir
cd builddir
python -c 'import fib2'
Traceback (most recent call last):
File "<string>", line 1, in <module>
ImportError: fib2.cpython-39-x86_64-linux-gnu.so: undefined symbol: FIB_
# Check this isn't a false positive
nm -A fib2.cpython-39-x86_64-linux-gnu.so | grep FIB_
fib2.cpython-39-x86_64-linux-gnu.so: U FIB_

回想一下，原始示例（如下所示）使用的是大写字母（SCREAMCASE）。

C FILE: FIB1.F
      SUBROUTINE FIB(A,N)
C
C     CALCULATE FIRST N FIBONACCI NUMBERS
C
      INTEGER N
      REAL*8 A(N)
      DO I=1,N
         IF (I.EQ.1) THEN
            A(I) = 0.0D0
         ELSEIF (I.EQ.2) THEN
            A(I) = 1.0D0
         ELSE 
            A(I) = A(I-1) + A(I-2)
         ENDIF
      ENDDO
      END
C END FILE FIB1.F

通过标准方法，暴露给 Python 的子程序是 fib，而不是 FIB。这意味着我们有几种选择。一种方法（在可能的情况下）是将原始 Fortran 文件小写，例如使用：

tr "[:upper:]" "[:lower:]" < fib1.f > fib1.f
python -m numpy.f2py fib1.f -m fib2
meson --wipe builddir
meson compile -C builddir
cd builddir
python -c 'import fib2'

但是，这需要修改源文件的能力，而这种情况并非总是可能。解决此问题的最简单方法是让 f2py 来处理它。

python -m numpy.f2py fib1.f -m fib2 --lower
meson --wipe builddir
meson compile -C builddir
cd builddir
python -c 'import fib2'

自动化包装器生成#

上述工作流中的一个主要痛点是手动跟踪输入。尽管如此，考虑到 F2PY 和构建系统中讨论的原因，确定实际输出需要更多的工作。

注意

从 NumPy 1.22.4 版本开始，f2py 将根据输入文件的 Fortran 标准（F77 或更高版本）确定性地生成包装器文件。可以将 --skip-empty-wrappers 传递给 f2py，以恢复以前仅在输入需要时生成包装器的行为。

但是，我们可以以一种直接的方式增强我们的工作流程，以考虑在设置构建系统时已知输出的文件的输入。

project('f2py_examples', 'c',
  version : '0.1',
  license: 'BSD-3',
  meson_version: '>=0.64.0',
  default_options : ['warning_level=2'],
)

add_languages('fortran')

py_mod = import('python')
py = py_mod.find_installation(pure: false)
py_dep = py.dependency()

incdir_numpy = run_command(py,
  ['-c', 'import os; os.chdir(".."); import numpy; print(numpy.get_include())'],
  check : true
).stdout().strip()

incdir_f2py = run_command(py,
    ['-c', 'import os; os.chdir(".."); import numpy.f2py; print(numpy.f2py.get_include())'],
    check : true
).stdout().strip()

fibby_source = custom_target('fibbymodule.c',
  input : ['fib1.f'],  # .f so no F90 wrappers
  output : ['fibbymodule.c', 'fibby-f2pywrappers.f'],
  command : [py, '-m', 'numpy.f2py', '@INPUT@', '-m', 'fibby', '--lower']
)

inc_np = include_directories(incdir_numpy, incdir_f2py)

py.extension_module('fibby',
  ['fib1.f', fibby_source],
  incdir_f2py / 'fortranobject.c',
  include_directories: inc_np,
  dependencies : py_dep,
  install : true
)

这可以像以前一样进行编译和运行。

rm -rf builddir
meson setup builddir
meson compile -C builddir
cd builddir
python -c "import numpy as np; import fibby; a = np.zeros(9); fibby.fib(a); print (a)"
# [ 0.  1.  1.  2.  3.  5.  8. 13. 21.]

要点#

以下几点值得牢记：

在此上下文中无法使用大写字母（SCREAMCASE），因此 .f 文件中的内容或生成的包装器 .c 文件需要转换为小写字母；这可以通过 F2PY 的 --lower 选项来实现。

使用 Meson#

斐波那契教程 (F77)#

自动化包装器生成#

要点#

使用 `Meson`#